Wayzata's Best of Shareware for Macintosh/CD Line - Limited Edition Wayzata's Best of Shareware for Macintosh for MacWorld Exposition Milano 1994 (050594)(1994).iso/pc/utilitie/system_7/hyperkey/key_stor.1

Text File | 1992-05-09 | 3KB | 135 lines

On DoControlC
 put the selectedchunk
End DoControlC

On DoControlD
 if the optionkey is down then type the short date
  else type the long date
End DoControlD

On DoControlF
 put the selectedfield
End DoControlF

On DoControlG
 beep
End DoControlG

On DoControlH
 visual effect iris open slowly
  go stack "Hyperkeys" in a new window
End DoControlH

On DoControlL
 -- Unlock/Lock card or background field below the cursor
  repeat with x = the number of card fields down to 1
    if the mouseloc is within the rect of cd fld x and the visible of cd fld x is true then
      set the locktext of cd fld x to not the locktext of cd fld x
      exit doControlL
    end if
  end repeat
  repeat with x = the number of fields down to 1
    if the mouseloc is within the rect of fld x and the visible of fld x is true then
      set the locktext of fld x to not the locktext of fld x
      exit doControlL
    end if
  end repeat
End DoControlL

On DoControlM
set cursor to cross
repeat until the mouse is down
put the mouseloc into temp
put temp&&"to 0,0"
end repeat
repeat until the mouse is up
put temp&&"to"&&the mouseloc
end repeat

End DoControlM

On DoControlT
 type the short time
End DoControlT

On DoControlU
 Set the userlevel to 5
End DoControlU

On DoControlB
 domenu "Battery"
End DoControlB

On DoControlR
 reset menubar
End DoControlR

On DoControlSpace
 set the visible of msg to not the visible of msg
End DoControlSpace

On DoControlSlash
 go stack "hypertalk reference" in a new window
End DoControlSlash

On DoControlOne
 Go first card
End DoControlOne

On DoControlTwo
 Go prev card
End DoControlTwo

On DoControlThree
 Go Next card
End DoControlThree

On DoControlFour
 Go Last card
End DoControlFour

On DoControlA
 go stack "Spinning Jenny:Desktop Folder:AppleEvent Monitor" in a new window
End DoControlA

On DoControlV
 if the visible of window "variable watcher" then hide window "variable watcher"
  else show window "variable watcher"
End DoControlV

On DoControlW
 if the visible of window "message watcher" then hide window "message watcher"
  else show window "message watcher"
End DoControlW

On DoControlE
 if the optionkey is down then
    answer file "Export scripts of what stack?" of type "STAK"
    if (it is empty) or (the result is "Cancel") then exit doControlE
    put it into srcFile
  else
    put the long name of this stack into srcFile
    delete word 1 of srcFile
    delete char 1 of srcFile
    delete last char of srcFile
  end if
  put lastHCItem(":",srcFile) && "Export" into destFileName
  ask file "Save file as:" with destFileName
  if (it is empty) or (the result is "Cancel") then exit DoControlE
  put it into destFile
  archiveScripts srcFile,destFile
End DoControlE

On DoControlS
 -- Show Clipboard contents if a PICT is on it
  picture "The Clipboard",clipboard
  if the result is not empty then
    put the result into Res
    put "Unable to display Clipboard." into temp
    if last word of res is "-102." then put " The clipboard contents are not PICT." after temp
    if last word of res is "memory." then put " Not enough memory to show contents." after temp
    answer temp
  end if
End DoControlS